IoT Laundry Notification

/*
  Digi-Key Electronics
  Kyle Meier
  2018

  Laundry Push Notification Project - MKR1000 and Adafruit MMA8451 accelerometer eval board

  This project uses the Blynk Service - www.blynk.cc
  Please follow the instructions here to get setup with Blynk: www.blynk.cc/getting-started/

  http://docs.blynk.cc/#getting-started-getting-started-with-the-blynk-app

  A few libraries are required:

  WiFi101.h                    // From Arduino library manager- see here for more details: https://www.arduino.cc/en/Reference/WiFi101
  BlynkSimpleWiFiShield101.h   // https://github.com/blynkkk/blynk-library/releases/latest
  Adafruit_MMA8451.h           // https://github.com/adafruit/Adafruit_MMA8451_Library/archive/master.zip
  Adafruit_Sensor.h            // https://github.com/adafruit/Adafruit_Sensor/archive/master.zip


  Set ssid and pass to the wireless network name and password you'll be using.
  Set Auth value to the authentication code provided from Blynk service after registration.

  To adjust sensitivity, change "tolerance" variable value. Lower values increase sensitivity.

  Hex Addresses for i2c sensors:
  Sensor 1 ("A" pin left open/on board pullup) - Put this accelerometer in the enclosure you want to place on the washer
  0x1D

  Sensor 2 ("A" pin soldered to ground) - Put this accelerometer in the enclosure you want to place on the dryer
  0x1C

  Parts of this code are from Adafruit, Blynk, and Arduino example codes. Credit to the authors.

*/


#include <SPI.h>

// *************************** DOWNLOAD THESE LIBRARIES:
#include <WiFi101.h>                    // From Arduino library manager- see here for more details: https://www.arduino.cc/en/Reference/WiFi101
#include <BlynkSimpleWiFiShield101.h>   // https://github.com/blynkkk/blynk-library/releases/latest
#include <Adafruit_MMA8451.h>           // https://github.com/adafruit/Adafruit_MMA8451_Library/archive/master.zip
#include <Adafruit_Sensor.h>            // https://github.com/adafruit/Adafruit_Sensor/archive/master.zip

Adafruit_MMA8451 mma = Adafruit_MMA8451();
Adafruit_MMA8451 mma2 = Adafruit_MMA8451();

// You should get an Auth Token in the Blynk App.
// Go to the Project Settings (nut icon).
char auth[] = "AUTHENTICATION CODE HERE";

// Your WiFi credentials.
// Set password to "" for open networks.
char ssid[] = "NETWORK NAME HERE";
char pass[] = "PASSWORD HERE";

BlynkTimer timer;

// ************************ Global Variable Declaration ************************

bool last60Wash[60];      // This array will store the last 60 sensor readings as a 1 or 0, movement or no movement respectively. This way we can determine if on average there was or was not movement in the last 60 readings (Seconds).
float lastXWash = 0;      // Initialize global variables to track movement/acceleration in X and Y axis
float lastYWash = 0;
int arrayLocation = 0;    // This variable keeps track of the position within the array we are writing to.
int lastArraySumWash;     // This variable is used to track differences between current reading and previous reading of array

bool last60Dry[60];
float lastXDry = 0;
float lastYDry = 0;
int lastArraySumDry;
// *****************************************************************************

void setup()
{
  for (int i = 0; i < 60; i++) { // For loop to clear all array locations in array last60Wash & Dry are set to 0 before start
    last60Wash[i] = 0;
    last60Dry[i] = 0;
  }

  SerialUSB.begin(9600);          // Begin Serial communication with computer for debugging
  Blynk.begin(auth, ssid, pass);  // Begin communication with Blynk service

  // Blynk.notify("Device started");  // Uncomment (remove "//" at the beginning of this line) to receive a notification from Blynk when the device is powered on
  SerialUSB.println("Adafruit MMA8451 test!");
  if (! mma.begin(0x1C)) {                            // Washer sensor- hex address of 0x1C. This sensor will have the "A" pin soldered to GND and be placed in the small enclosure.
    Serial.println("Couldnt start first sensor");
    while (1);
  }

  if (! mma2.begin(0x1D)) {                           // Dryer sensor- hex address of 0x1D. This sensor will have the "A" pin open/disconnected.
    Serial.println("Couldnt start second sensor");
    while (1);
  }
  
  SerialUSB.println("MMA8451 found!");

  mma.setRange(MMA8451_RANGE_2_G);
  mma2.setRange(MMA8451_RANGE_2_G);

  timer.setInterval(1000L, readSensor); // A timer to read sensor values every 1 second. It will call the readSensor function
}


void loop()
{
  Blynk.run();
  timer.run();
}


void readSensor()
{
  
  sensors_event_t event;    // Read sensor values
  sensors_event_t event2; 
  mma.getEvent(&event);
  mma2.getEvent(&event2);

  float xDiffWash = (event.acceleration.x - lastXWash); // Read x and y acceleration values- xDiffWash and yDiffWash determine difference between previous value and current value
  float yDiffWash = (event.acceleration.y - lastYWash);
  xDiffWash = abs(xDiffWash); // Because the acceleration values can be positive or negative, make the values absolute for easier indication
  yDiffWash = abs(yDiffWash);

  float xDiffDry = (event2.acceleration.x - lastXDry); // Read x and y acceleration values- xDiffDry and yDiffDry determine difference between previous value and current value
  float yDiffDry = (event2.acceleration.y - lastYDry);
  xDiffDry = abs(xDiffDry); // Because the acceleration values can be positive or negative, make the values absolute for easier indication
  yDiffDry = abs(yDiffDry);

  SerialUSB.print("xDiffWash: "); SerialUSB.print(xDiffWash); SerialUSB.print("\t"); // Serial print acceleration variables for testing
  SerialUSB.print("yDiffWash: "); SerialUSB.print(yDiffWash); SerialUSB.print("\t");
  SerialUSB.println();

  SerialUSB.print("xDiffDry: "); SerialUSB.print(xDiffDry); SerialUSB.print("\t"); // Serial print acceleration variables for testing
  SerialUSB.print("yDiffDry: "); SerialUSB.print(yDiffDry); SerialUSB.print("\t");
  SerialUSB.println();

  arrayLocation++; // Increment arrayLocation variable. This variable increments the array location we are recording to in each loop.
  if (arrayLocation == 60) arrayLocation = 0; // If variable has reached 60, reset to zero to cycle through the array.
  
  float tolerance = 0.25;
  /********************************************************************************************************************************************************************  
      This tolerance value is the acceleration tolerance for movement. It is the sensitivity, adjust as needed. I found 0.25 worked well for both my washer and dryer.
      My laundry room has a concrete floor, however, and will not move like machines mounted on a wood floor which may be sensitive to nearby foot traffic.
      Lower value = higher sensitivity 
  ********************************************************************************************************************************************************************/

  if ((xDiffWash > tolerance) || (yDiffWash > tolerance))     // If the acceleration differences are larger than the tolerance value
  {
    if (xDiffWash > tolerance) SerialUSB.print ("X ");    // Serial print which axes exceeded the tolerance value
    if (yDiffWash > tolerance) SerialUSB.print ("Y ");
    SerialUSB.println("OVER");
    last60Wash[arrayLocation] = 1; // Movement occured, store a "1" in the current array location
  }
  else last60Wash[arrayLocation] = 0; // Movement did not occur, store a "0" in the current array location


  if ((xDiffDry > tolerance) || (yDiffDry > tolerance))     // If the acceleration differences are larger than the tolerance value
  {
    if (xDiffDry > tolerance) SerialUSB.print ("X ");    // Serial print which axes exceeded the tolerance value
    if (yDiffDry > tolerance) SerialUSB.print ("Y ");
    SerialUSB.println("OVER");
    last60Dry[arrayLocation] = 1; // Movement occured, store a "1" in the current array location
  }
  else last60Dry[arrayLocation] = 0; // Movement did not occur, store a "0" in the current array location


  for (int i = 0; i < 60; i++) {  // Display the full array via Serial monitor
    SerialUSB.print(last60Wash[i]);
    SerialUSB.print(", ");
    if (i == 59) SerialUSB.println();
  }

  for (int i = 0; i < 60; i++) {  // Display the full array via Serial monitor
    SerialUSB.print(last60Dry[i]);
    SerialUSB.print(", ");
    if (i == 59) SerialUSB.println();
  }

  int arraySumWash = 0;   // This variable stores a sum of the values within the array
  int arraySumDry = 0;
  for (int i = 0; i < 60; i++) {    // For loop to add all the values of the array
    arraySumWash += last60Wash[i];
    arraySumDry += last60Dry[i];
  }

  SerialUSB.print("arraySumWash: ");
  SerialUSB.print(arraySumWash);
  SerialUSB.print(" lastArraySumWash: ");
  SerialUSB.println(lastArraySumWash);

  SerialUSB.print("arraySumDry: ");
  SerialUSB.print(arraySumDry);
  SerialUSB.print(" lastArraySumDry: ");
  SerialUSB.println(lastArraySumDry);

  if ((arraySumWash == 20) && (lastArraySumWash == 19)) {       // If arraySumWash is increasing in value and increased from 19 to 20, send push notification that the washer has been started
    Blynk.notify("Washer Started");
    SerialUSB.println("Washer Started");
  }
  else if ((arraySumWash == 19) && (lastArraySumWash == 20)) {  // If arraySumWash is decreasing in value and decreased from 20 to 19, send push notification that the washer has finished
    Blynk.notify("Washer Finished");
    SerialUSB.println("Washer Finished");
  }

  if ((arraySumDry == 20) && (lastArraySumDry == 19)) {
    Blynk.notify("Dryer Started");
    SerialUSB.println("Dryer Started");
  }
  else if ((arraySumDry == 19) && (lastArraySumDry == 20)) {
    Blynk.notify("Dryer Finished");
    SerialUSB.println("Dryer Finished");
  }
  SerialUSB.println();

  lastXWash = event.acceleration.x;     // Store current acceleration values in lastXWash and lastYWash variables for calculations at beginning of the void loop
  lastYWash = event.acceleration.y;
  lastArraySumWash = arraySumWash;      // Store the arraySumWash value in variable lastArraySumWash to compare in the next reading

  lastXDry = event2.acceleration.x;
  lastYDry = event2.acceleration.y;
  lastArraySumDry = arraySumDry;
}